東ロボくんのこと（３）

第１問　全体としてのポイントは関数gを対応と捉える所です．
まず，gのグラフに(t,u)が属する条件を求めます．
実際の問題文は幾何学的に表現されているので，機械での翻訳はかなり難しそう．

In[1]:= G[t_, u_] := 
 Reduce[Exists[{p, q}, 
   ForAll[x, x*(x - 1)*(x - 3) - t*x == x*(x - p)*(x - q)] && 
    u == Sqrt[(p^2 + (t*p)^2)*(q^2 + (t*q)^2)]], {t, u}, Reals]

In[2]:= G[t, u] // Factor

Out[2]= (-1 <= t <= 3 && u == -(-3 + t) (1 + t^2)) || (t > 3 && 
   u == (-3 + t) (1 + t^2))

次に，制限が狭義の増加，減少関数となる範囲にtが属する条件を求めます．
これは定義通りの立式なので，ルーチンとして用意すれば大丈夫かな．

In[3]:= inc = 
 Reduce[Exists[{a, b}, 
   a <= t <= b && a < b && Exists[{ga, gb}, G[a, ga] && G[b, gb]] && 
    ForAll[{s, gs, t, gt}, G[s, gs] && G[t, gt] && a <= s < t <= b, 
     gs < gt]], t, Reals]

Out[3]= 1/3 (3 - Sqrt[6]) <= t <= 1/3 (3 + Sqrt[6]) || t >= 3

In[4]:= dec = 
 Reduce[Exists[{a, b}, 
   a <= t <= b && a < b && Exists[{ga, gb}, G[a, ga] && G[b, gb]] && 
    ForAll[{s, gs, t, gt}, G[s, gs] && G[t, gt] && a <= s < t <= b, 
     gs > gt]], t, Reals]

Out[4]= -1 <= t <= 1/3 (3 - Sqrt[6]) || 1/3 (3 + Sqrt[6]) <= t <= 3

最後に，上記の範囲の交わりを定義域とするgの値域にvが属する条件を求めます．
文科の出題なら

（極値を取る値全体）＝（制限が狭義増加となる範囲）∩（制限が狭義減少となる範囲）

で良い筈．

In[5]:= Reduce[Exists[t, inc && dec && G[t, v]]] // Factor

Out[5]= 
v == 0 || v == -(4/9) (-9 + Sqrt[6]) || v == 4/9 (9 + Sqrt[6])